Text Displays

When a value needs more than digits — "COM1 118.750", "XPDR 7000 ALT", a page of a radio stack — a character LCD or a small OLED does the job. Both sit on the ESP32's I²C bus , so they cost no extra pins beyond SDA and SCL, and both are treated as a grid of character cells.

A bare HD44780 needs six or more pins. Buy it with a PCF8574 I²C backpack soldered on (or solder one yourself) and it needs only the two bus wires plus power. The backpack carries a contrast trimmer — if the screen powers up showing nothing or a row of solid blocks, turn it until the characters appear — and a jumper that switches the backlight .

Arduino code

// 20×4 character LCD on a PCF8574 backpack (LiquidCrystal_I2C library)
#include <Wire.h>
#include <LiquidCrystal_I2C.h>

LiquidCrystal_I2C lcd(0x27, 20, 4);   // address, columns, rows

void setup() {
    Wire.begin(21, 22);               // SDA, SCL
    lcd.init();
    lcd.backlight();
    lcd.setCursor(0, 0);              // column 0, row 0
    lcd.print("COM1 118.750");
    lcd.setCursor(0, 1);
    lcd.print("STBY 121.500");
}

void loop() {}

The common 0.96" and 1.3" OLED modules are 128 pixels wide and 64 or 32 high, driven by an SSD1306 or an SH1106 (most 1.3" modules). The two chips need different drivers, so check which one your module has. They run on 3.3 V and wire straight to the bus. The address is 0x3C , or 0x3D with the address jumper on the back moved.

Arduino code

// 128×64 SSD1306 OLED (Adafruit_SSD1306 library)
#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>

Adafruit_SSD1306 oled(128, 64, &Wire, -1);

void setup() {
    Wire.begin(21, 22);
    oled.begin(SSD1306_SWITCHCAPVCC, 0x3C);
    oled.clearDisplay();
    oled.setTextSize(1);              // 6×8 cells: 21 columns × 8 rows
    oled.setTextColor(SSD1306_WHITE);
    oled.setCursor(0, 0);
    oled.print("XPDR 7000 ALT");
    oled.display();
}

void loop() {}

One screen almost always shows several independent values — a radio's active and standby frequency on one 20×4 LCD, for example. So rather than binding the whole screen, you divide it into Text Fields : a run of character cells on one row, given by its row , starting column and width . Each field shows one value.

The text a field receives is final: it is drawn left-aligned, cut to the field's width, and the rest of the field is blanked. Characters outside printable ASCII show as blanks. Two fields on the same row must not overlap.

// Write one field: left-aligned, cut to its width, rest blanked
void writeField(uint8_t row, uint8_t column, uint8_t width, const char* text) {
    lcd.setCursor(column, row);
    for (uint8_t i = 0; i < width; i++) {
        char c = text[i];
        if (c == '\0') {
            break;
        }
        lcd.write(c >= 32 && c <= 126 ? c : ' ');
    }
    for (uint8_t i = strlen(text); i < width; i++) {
        lcd.write(' ');
    }
}

// Two independent values on one screen
writeField(0, 5, 7, "118.750");   // COM1 active
writeField(1, 5, 7, "121.500");   // COM1 standby

On a CockpitConnect controller you don't write this: add the LCD or OLED to the controller in the Flow Builder, place a Text Field node per value, and bind it to a dataref. Right alignment, padding, decimals and units come from the Mapping's format or lookup , so the screen shows exactly what the Flow sent.